awk 스크립트에서 쉘 변수를 사용하는 방법

bash shell awk


외부 셸 변수를 awk 스크립트 에 전달하는 몇 가지 방법을 찾았 지만 '" 에 대해 혼란 스럽습니다 .

먼저 쉘 스크립트를 사용해 보았습니다.

$ v=123test
$ echo $v
123test
$ echo "$v"
123test

그런 다음 awk를 시도했습니다.

$ awk 'BEGIN{print "'$v'"}'
$ 123test
$ awk 'BEGIN{print '"$v"'}'
$ 123

왜 차이점이 있습니까?

마지막으로 나는 이것을 시도했다 :

$ awk 'BEGIN{print " '$v' "}'
$  123test
$ awk 'BEGIN{print ' "$v" '}'
awk: cmd. line:1: BEGIN{print
awk: cmd. line:1:             ^ unexpected newline or end of string 

나는 이것에 대해 혼란스러워한다.





Answer 1 Jotne


쉘 변수를 awk 로 가져 오기

여러 가지 방법으로 수행 될 수 있습니다. 일부는 다른 것보다 낫습니다. 이것은 대부분을 다루어야합니다. 의견이 있으시면 아래에 남겨주세요. v1.5


-v 사용 (가장 좋은 방법)

사용 -v 옵션 : (PS는 뒤에 공백을 사용 -v 또는 덜 휴대용 될 것입니다 예. awk -v var= 하지 awk -vvar= )

variable="line one\nline two"
awk -v var="$variable" 'BEGIN {print var}'
line one
line two

이것은 대부분의 awk 와 호환 가능해야하며 변수는 BEGIN 블록에서도 사용할 수 있습니다.

여러 변수가있는 경우 :

awk -v a="$var1" -v b="$var2" 'BEGIN {print a,b}'

경고 . Ed Morton이 쓴 것처럼 이스케이프 시퀀스는 해석되므로 \t 는 실제 tab 되고 검색하는 경우 \t 가 아닙니다 . ENVIRON[] 을 사용하여 해결 하거나 ARGV[] 를 통해 액세스 할 수 있습니다

PS 세 개의 세로 막대를 분리 자로 사용하려면 ||| 이스케이프 할 수 없으므로 -F"[|][|][|]"

프로그램 / 함수 여관에서 awk 로 데이터를 가져 오는 예제 (여기서는 날짜가 사용됨)

awk -v time="$(date +"%F %H:%M" -d '-1 minute')" 'BEGIN {print time}'

코드 블록 후 변수

여기서 awk 코드 다음에 변수를 얻습니다 . BEGIN 블록에 변수가 필요하지 않으면 제대로 작동합니다 .

variable="line one\nline two"
echo "input data" | awk '{print var}' var="${variable}"
or
awk '{print var}' var="${variable}" file
  • 여러 변수 추가하기 :

awk '{print a,b,$0}' a="$var1" b="$var2" file

  • 이러한 방식으로 각 파일마다 다른 Field Separator FS 를 설정할 수도 있습니다.

awk 'some code' FS=',' file1.txt FS=';' file2.ext

  • 코드 블록 뒤의 변수는 BEGIN 블록에서 작동하지 않습니다 .

echo "input data" | awk 'BEGIN {print var}' var="${variable}"


Here-string

변수 를 지원하는 쉘 의 here-string 을 사용하여 awk 에 변수를 추가 할 수도 있습니다 (Bash 포함).

awk '{print $0}' <<< "$variable"
test

이것은 다음과 같습니다 :

printf '%s' "$variable" | awk '{print $0}'

PS 변수를 파일 입력으로 취급합니다.


ENVIRON 입력

TrueY가 쓰는 것처럼 ENVIRON 을 사용하여 환경 변수 를 인쇄 할 수 있습니다 . AWK를 실행하기 전에 변수를 설정하면 다음과 같이 인쇄 할 수 있습니다.

X=MyVar
awk 'BEGIN{print ENVIRON["X"],ENVIRON["SHELL"]}'
MyVar /bin/bash

ARGV 입력

Steven Penny가 쓴 것처럼 ARGV 를 사용 하여 데이터를 awk로 가져올 수 있습니다 .

v="my data"
awk 'BEGIN {print ARGV[1]}' "$v"
my data

BEGIN뿐만 아니라 코드 자체로 데이터를 가져 오려면 :

v="my data"
echo "test" | awk 'BEGIN{var=ARGV[1];ARGV[1]=""} {print var, $0}' "$v"
my data test

코드 내 변수 : USE WITH주의

awk 코드 내에서 변수를 사용할 수 있지만 지저분하고 읽기가 어렵습니다. Charles Duffy 가 지적 했듯이이 버전은 코드 삽입의 희생자 일 수 있습니다. 누군가 변수에 나쁜 것을 추가하면 awk 코드의 일부로 실행됩니다 .

이것은 코드 내에서 변수를 추출하여 작동하므로 일부가됩니다.

변수를 사용하여 동적으로 변경 되는 awk 를 만들려면 이 방법으로 수행 할 수 있지만 일반 변수에는 사용하지 마십시오.

variable="line one\nline two"
awk 'BEGIN {print "'"$variable"'"}'
line one
line two

코드 삽입의 예는 다음과 같습니다.

variable='line one\nline two" ; for (i=1;i<=1000;++i) print i"'
awk 'BEGIN {print "'"$variable"'"}'
line one
line two
1
2
3
.
.
1000

당신은에 많은 명령을 추가 할 수 있습니다 awk 이런 식으로. 유효하지 않은 명령으로도 충돌이 발생합니다.


추가 정보 :

큰 따옴표 사용

변수 "$variable" 을 큰 따옴표로 묶는 것이 좋습니다.
그렇지 않으면 여러 줄이 긴 단일 줄로 추가됩니다.

Example:

var="Line one
This is line two"

echo $var
Line one This is line two

echo "$var"
Line one
This is line two

큰 따옴표없이 얻을 수있는 다른 오류 :

variable="line one\nline two"
awk -v var=$variable 'BEGIN {print var}'
awk: cmd. line:1: one\nline
awk: cmd. line:1:    ^ backslash not last character on line
awk: cmd. line:1: one\nline
awk: cmd. line:1:    ^ syntax error

작은 따옴표로 변수의 값을 확장하지 않습니다.

awk -v var='$variable' 'BEGIN {print var}'
$variable

AWK 및 변수에 대한 추가 정보

이 FAQ를 읽으십시오 .




Answer 2 TrueY


오래된 ENVIRON awk 내장 해시는 전혀 언급되지 않은 것 같습니다 . 사용법의 예 :

$ X=Solaris awk 'BEGIN{print ENVIRON["X"], ENVIRON["TERM"]}'
Solaris rxvt



Answer 3 Ed Morton


처리 된 쉘 변수에서 백 슬래시를 원하는 방식에 따라 다음 중 하나를 사용하십시오 ( avar 는 awk 변수, svar 는 쉘 변수).

awk -v avar="$svar" '... avar ...' file
awk 'BEGIN{avar=ARGV[1];ARGV[1]=""}... avar ...' "$svar" file

자세한 내용 및 기타 옵션 은 http://cfajohnson.com/shell/cus-faq-2.html#Q24 를 참조 하십시오 . 위의 첫 번째 방법은 거의 항상 최선의 선택이며 가장 명확한 의미가 있습니다.




Answer 4 Johnsyweb


변수 이름 ( v )과 환경 변수 ( "${v}" ) 의 값 ( = ) 과 함께 명령 행 옵션 -v 를 전달할 수 있습니다 .

% awk -vv="${v}" 'BEGIN { print v }'
123test

또는 더 명확하게하기 위해 ( v 가 훨씬 적음 ) :

% environment_variable=123test
% awk -vawk_variable="${environment_variable}" 'BEGIN { print awk_variable }'
123test



Answer 5 Steven Penny


ARGV를 활용할 수 있습니다 :

v=123test
awk 'BEGIN {print ARGV[1]}' "$v"

몸에 계속 들어가려면 ARGC를 조정해야합니다.

awk 'BEGIN {ARGC--} {print ARGV[2], $0}' file "$v"